win10備份還原密鑰 win10+激活id備份工具

今天跟著小編一起來看看Windows10查詢已激活係統的密鑰及備份還原密鑰方法。

方法一：製作一個【密鑰查詢.vbs】文件可以查詢已激活係統的密鑰及備份密鑰。

把下麵的內容複製到記事本中：

————————————————————————————————

Option Explicit

Dim objshell,path,DigitalID, Result

Set objshell = CreateObject("WScript.Shell")

'Set registry key path

Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"

'Registry key value

DigitalID = objshell.RegRead(Path & "DigitalProductId")

Dim ProductName,ProductID,ProductKey,ProductData

'Get ProductName, ProductID, ProductKey

ProductName = "係統名稱：" & objshell.RegRead(Path & "ProductName")

ProductID = "產品ID：" & objshell.RegRead(Path & "ProductID")

ProductKey = "已安裝密鑰：" & ConvertToKey(DigitalID)

ProductData = ProductName & vbNewLine & ProductID & vbNewLine & ProductKey

'Show messbox if save to a file

If vbYes = MsgBox(ProductData & vblf & vblf & "要將密鑰保存到文件嗎？", vbYesNo + vbQuestion, "軟媒魔方備份Windows密鑰信息") then

Save ProductData

End If

'Convert binary to chars

Function ConvertToKey(Key)

Const KeyOffset = 52

Dim isWin10, Maps, i, j, Current, KeyOutput, Last, keypart1, insert

'Check if OS is Windows 10

isWin10 = (Key(66) \ 6) And 1

Key(66) = (Key(66) And &HF7) Or ((isWin10 And 2) * 4)

i = 24

Maps = "BCDFGHJKMPQRTVWXY2346789"

Do

Current= 0

j = 14

Do

Current = Current* 256

Current = Key(j + KeyOffset) + Current

Key(j + KeyOffset) = (Current \ 24)

Current=Current Mod 24

j = j -1

Loop While j >= 0

i = i -1

KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput

Last = Current

Loop While i >= 0

If (isWin10 = 1) Then

keypart1 = Mid(KeyOutput, 2, Last)

insert = "N"

KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0)

If Last = 0 Then KeyOutput = insert & KeyOutput

End If

ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5)

End Function

'Save data to a file

Function Save(Data)

Dim fso, fName, txt,objshell,UserName

Set objshell = CreateObject("wscript.shell")

'Get current user name

UserName = objshell.ExpandEnvironmentStrings("%UserName%")

'Create a text file on desktop

fName = "C:\Users\" & UserName & "\Desktop\Windows密鑰備份.txt"

Set fso = CreateObject("Scripting.FileSystemObject")

Set txt = fso.CreateTextFile(fName)

txt.Writeline Data

txt.Close

End Function

————————————————————————————————

點擊記事本左下角的【文件】，在下拉菜單中點擊【另存為】；

在打開的另存為窗口，點擊【桌麵】，在文件名（N）欄中輸入：密鑰查詢.vbs，再點擊：保存；

我們保存密鑰查詢.vbs文件後，在係統桌麵上顯示一個【密鑰查詢.vbs】文件圖標，左鍵雙擊【密鑰查詢.vbs】文件圖標，打開一個軟媒魔方備份Windows密鑰信息對話框，顯示了係統名稱、產品ID和已安裝密鑰。

如果需要保存安裝密鑰，點擊：是（Y），則安裝密鑰就會以記事本的方式保存到係統桌麵上。

方法二：使用第三方軟件軟媒魔方中的Windows激活備份程序來備份、還原係統激活文件。

下載、安裝、啟動軟媒魔方軟件，點擊右下角的【應用大全】；

在應用大全的設置向導窗口，找到並點擊【Windows激活備份】；

在打開的Win7/Win8（Win10係統可用） 激活文件備份還原窗口，點擊【備份係統激活文件】；

在瀏覽文件夾窗口，❶點擊【新建文件夾】，❷把新建的文件夾命名為：係統激活文件（或其他名稱），❸點擊：確定；

點擊確定以後，彈出一個提示對話框：備份Windows8（實際是Windows10）激活文件成功，點擊：確定。

如果需要還原係統激活文件，隻要在Win7/Win8 激活文件備份還原窗口，點擊【還原係統激活文件】；

在打開的瀏覽文件夾窗口，點擊【係統激活文件】文件夾，再點擊：確定；

我們點擊確定以後，即彈出一個提示對話框：還原Windows8（實際為Windows10）激活文件成功！點擊：確定。

關於Windows10查詢已激活係統密鑰及備份還原密鑰的方法就分享到這裏了，感興趣的朋友不妨試試上麵的方法。